ConformableD

Calculate the conformable fractional derivative

DefinitionResourceCreateNotebook

ClearAll[ConformableD]
Options[ConformableD]={Assumptions->None};
ConformableD::usage="ConformableD[f, {x, α}] gives the conformable fractional derivative (Subscript[T, α])(f)(x) of order α of the function f.";
ConformableD::neg="The conformable derivative order `1` is not non-negative.";
ConformableD::ord="The conformable derivative order `1` is not a real number.";
ConformableD[_,{_,α_?NumericQ}]/;!Element[α,Reals]:=(Message[ConformableD::ord,α];$Failed)
ConformableD[_,{_,α_?Negative}]:=(Message[ConformableD::neg,α];$Failed)
ConformableD[f_,{x_,0},opts:OptionsPattern[]]/;Not@FreeQ[f,x]:=x D[f,x]
ConformableD[f_,{x_,α_},opts:OptionsPattern[]]/;Not@FreeQ[f,x]:=
Refine[
x^(Ceiling[α]-α)D[f,{x,Ceiling[α]}],
OptionValue[Assumptions]
]

Documentation

UsageResourceCreateNotebook

Details & OptionsResourceCreateNotebook

The conformable fractional derivative is a natural generic derivative on fractional orders introduced by Khalil et al (2014), see https://doi.org/10.1016/j.cam.2014.01.002 for details.

The basic definition is made on α∈[0,1) as follows: (Subscript[T, α])(f)(x)=(lim_(ϵ->0))((f(x+ϵ (x^(1-α)))-f(x))/ϵ) for x>0, which can then be easily generalised for any α∈[n,n+1), n natural.

ConformableD[array,{x,α}] threads ConformableD over each element of array.

ConformableD takes different Assumptions on the parameters of the input functions.

All inputs free of the independent variable are treated as constants.

ExamplesResourceCreateNotebook

Basic Examples

Calculate the half-order conformable fractional derivative of a quadratic function with respect to x:

ConformableD[x,{x,1/2}]

In general, for 0<α<1, we have:

Assuming[
{α∈Reals,0<α<1},
Simplify@ConformableD[x,{x,α}]
]

Arbitrary-order fractional derivative of a function in x:

ConformableD[f[x],{x,α}]

Plot these for f(x)=(x^2):

Plot[Evaluate@Table[ConformableD[(x^2),{x,α}],{α,{0,1/2,9/10,1}}],
{x,0,1},PlotLegends->Thread[α=={0,1/2,9/10,1}]
]

Conformable fractional derivative of Sin:

fr=Table[
ConformableD[Sin[x],{x,α}],
{α,{1/2,9/10,2.5,3.5}}
]

Plot[fr,{x,0,10π}]

Conformable fractional derivative of MittagLefflerE:

ConformableD[MittagLefflerE[a,x],{x,0.8}]

Conformable fractional derivative of JacobiSN at various values of m:

Table[
ConformableD[JacobiSN[u,m],{u,α}],
{α,0,1,1/3}
]

Conformable fractional derivative of some transcedental functions:

ConformableD[{Exp[x],Log[x],Sinh[x]},{x,α}]

Scope

Conformable fractional derivative satisfies the product, quotient, and chain rules:

ConformableD[f[x]g[x],{x,1/2}]

ConformableD[f[x]/g[x],{x,1/2}]

ConformableD[f[g[x]],{x,1/2}]

Conformable derivative of the power function with respect to x:

ConformableD[(x^n),{x,α}]

For positive integral values of α, the conformable derivative coincides with the ordinary derivative:

ConformableD[(x^n),{x,2}]==D[(x^n),{x,2}]

Conformable derivatives of BesselJ function:

ConformableD[BesselJ[ν,x],{x,α}]

Conformable fractional derivatives of MeijerG function are given in terms of multiple MeijerG functions:

ConformableD[MeijerG[{{a1},{a2}},{{b1},{b2}},x],{x,α}]

FreeQ[%,MeijerG]

Options

Assumptions

By default, no assumptions are considered:

Simplify@ConformableD[(x^5),{x,α}]

Assuming 2<α<3:

ConformableD[(x^5),{x,α},Assumptions->{α∈Reals,2<α<3}]

Applications

Solve the basic conformable fractional differential equation (Subscript[T, α])(y)(x)=y(x):

DSolve[
ConformableD[f[x],{x,α},Assumptions->{α∈Reals,0<α<1}]==f[x],
f[x],x
]

Properties and Relations

ConformableD is defined for all positive and real values of α:

ConformableD[f,{x,-1}]

At the same time, α has to be real:

ConformableD[f,{x,I}]

The 0-order conformable fractional derivative of a function is not itself:

ConformableD[Sin[x],{x,0}]

Possible Issues

Neat Examples

Source & Additional Information

Contributed ByResourceCreateNotebook

Naman T.

KeywordsResourceCreateNotebook

fractional derivatives

conformal fractional derivatives

calculus

differentiability

CategoriesResourceCreateNotebook

Related SymbolsResourceCreateNotebook

Related Resource ObjectsResourceCreateNotebook

Resource Name (resources from any Wolfram repository)

Source/Reference CitationResourceCreateNotebook

Source, reference or citation information

LinksResourceCreateNotebook

https://doi.org/10.1016/j.cam.2014.01.002

https://doi.org/10.1016/j.cam.2014.10.016

TestsResourceCreateNotebook

VerificationTest[
ConformalD[x,{x,1/2}],
Sqrt[x]
]

VerificationTest[
ConformalD[x,{x,α},Assumptions->{α∈Reals,0<α<1}],
Power[x,1-α]
]

VerificationTest[
ConformalD[{x,y,(x^2)},{x,1/2}],
{Sqrt[x],0,2 Power[x,3/2]}
]

CompatibilityResourceCreateNotebook

Wolfram Language VersionResourceCreateNotebook

14.3+

Operating SystemResourceCreateNotebook

EnvironmentsResourceCreateNotebook

Cloud SupportResourceCreateNotebook

Required FeaturesResourceCreateNotebook

Author NotesResourceCreateNotebook

Additional information about limitations, issues, etc.

Submission NotesResourceCreateNotebook

Additional information for the reviewer.